MCSE技术论坛

'==========================================================================
'
' VBScript Source File -- Created with SAPIEN Technologies PrimalScript 4.1
'
' NAME:
'
' AUTHOR: Steven , Steven
' DATE  : 2007-8-18
'
' COMMENT:
'
'==========================================================================
Dim oRoot
Set oRoot=GetObject("LDAP://RootDSE")
sDomain = oRoot.Get("defaultNamingContext")
Set oDomain = GetObject("LDAP://" & sDomain)
JustDoIt oDomain
Sub JustDoIt(oContainer)
Dim oMyObject
For Each oMyObject in oContainer
  Select Case oMyObject.Class
'这个是用户的
  Case "user"
    oMyObject.put "displayName", "显示名字写在这儿"
    oMyObject.put "physicalDeliveryOfficeName", "办公室写在这儿"
    oMyObject.put "telephoneNumber", "电话写在这儿"
    oMyObject.put "mail", "电邮写在这儿"
    oMyObject.put "url", "网页写在这儿"
    oMyObject.put "st", "省市写在这儿"
    oMyObject.put "postalCode", "邮编写在这儿"
    oMyObject.put "co", "国家"
    oMyObject.put "postOfficeBox", "邮箱地址写在这儿"   
    oMyObject.put "streetAddress", "街道写在这儿"
    oMyObject.put "description", "描述写在这儿"
    oMyObject.SetInfo
'这个是电脑帐户的
  Case "computer"
    oMyObject.put "description", "描述写在这儿"
    oMyObject.SetInfo
'这个是ou和容器的   
  Case "organizationalUnit" , "container"
    oMyObject.put "description", "描述写在这儿"
    oMyObject.SetInfo
 
    JustDoIt(oMyObject)
  End select
Next
End Sub

原帖由 magicking 于 2007-8-17 22:00:00 发表
我想要个SMS高级客户端的卸载脚本

原帖由 uctip 于 2007-8-17 23:35:00 发表
通过计划任务作NTBACKUP的时候能自动生成以时间命名的备份文件么？

原帖由 happy_daily 于 2007-8-18 17:12:00 发表
楼主帮忙写一个可以枚举D盘下各用户创建文件的文件名,大小信息.

原帖由 happy_daily 于 2007-8-18 17:12:00 发表
楼主帮忙写一个可以枚举D盘下各用户创建文件的文件名,大小信息.

'==========================================================================
'
' VBScript Source File -- Created with SAPIEN Technologies PrimalScript 4.1
'
' NAME:
'
' AUTHOR: Steven , Steven
' DATE  : 2007-8-18
'
' COMMENT:
'
'==========================================================================
Set oFSO = CreateObject("Scripting.FileSystemObject")
Set oTFile = oFSO.CreateTextFile("C:\output.txt")
set objWMI = GetObject("winmgmts:")
Set oFiles = objWMI.ExecQuery ("select * from cim_datafile where Drive='D:'")
For Each oFile In oFiles
strFile = oFile.name
set colItems = objWMI.ExecQuery ("ASSOCIATORS OF {Win32_LogicalFileSecuritySetting='" & strFile & "'}" & " WHERE AssocClass=Win32_LogicalFileOwner ResultRole=Owner")
for Each objItem in colItems
    oTFile.WriteLine "文件名: " & ofile.name
    oTFile.WriteLine "创建用户: " & objItem.ReferencedDomainName & "\" & objItem.AccountName
        oTFile.WriteLine "大小: " & oFile.filesize
        oTFile.WriteLine "--------------------------------------------------------------------------"
Next
Next
oTFile.Close
WScript.Echo "完成!"

原帖由 lovereplicate 于 2007-10-20 16:34:00 发表
高手，帮我看看这个脚本错在哪里了？
xp+sp2环境，该脚本想实现：determine the domain in which a computer belongs?
————————————————————————
strComputer="."
Set objwM......

原帖由 long_xiao_me 于 2007-12-12 13:00:00 发表
楼主您好：帮忙写一个XP客户端的本地文件夹授予一个域帐号的完全控制权限。

由于XP系统里有一些程序需管理员权限才能运行，以前为了省事，给域帐号授予了本地管理员权限，现在发现问题很多，用户乱装程序，木马流......

Set objShell = CreateObject("Wscript.Shell")
IP = InputBox ("输入新的IP地址","IP地址")
NM="255.255.255.0" '子网掩码
GW=left(IP,8) & "1"  '网关
MDNS="10.10.10.10"  '首选DNS
SDNS="10.10.10.30"  '备用DNS
msgbox ChangeIP(IP,NM,GW,MDNS,SDNS)
Function ChangeIP(IP, NM, GW, MDNS, SDNS)
  Dim strComputer, objWMIService, colNetAdapters, strIPAddress, strSubnetMask
  Dim strGateway, strGatewaymetric, strDNS, objNetAdapter, errEnable, errGateways, errDNS
  strComputer = "RemotePCName"  '远程计算机名
  Set objWMIService = GetObject("winmgmts:\\" & strComputer & "\root\cimv2")
  Set colNetAdapters = objWMIService.ExecQuery("Select * from Win32_NetworkAdapterConfiguration where IPEnabled=TRUE")
  strIPAddress=Array(IP)
  strSubnetMask=Array(NM)
  strGateway=Array(GW)
  strDNS = Array(MDNS, SDNS)
  strGatewaymetric = Array(1)
  For Each objNetAdapter In colNetAdapters
    errEnable = objNetAdapter.EnableStatic(strIPAddress, strSubnetMask)
    errGateways = objNetAdapter.SetGateways(strGateway, strGatewaymetric)
    errDNS = objNetAdapter.SetDNSServerSearchOrder(strDNS)
    If errEnable = 0 And errGateways = 0 And errDNS = 0 Then
      ChangeIP = "设置成功"
    Else
      If errEnable = 0 Then
          ChangeIP = "IP地址和子网掩码设置成功, "
      Else
          ChangeIP = "IP地址或子网掩码设置失败, "
      End If
      If errGateways = 0 Then
          ChangeIP = ChangeIP & "默认网关设置成功, "
      Else
          ChangeIP = ChangeIP & "默认网关设置失败, "
      End If
      If errDNS = 0 Then
          ChangeIP = ChangeIP & "DNS设置成功"
      Else
          ChangeIP = ChangeIP & "DNS设置失败"
      End If
    End If
  Next
  End Function

Dim reval
Set objnet = CreateObject ("WScript.Network")
Set R = CreateObject("WScript.Shell")
reval = InputBox ("当前的计算机名是：" & objnet.ComputerName,"输入新的计算机名")
On Error Resume Next
strComputer = "RemotePCName"  '远程计算机名
Set objWMIService = GetObject("winmgmts:" _
    & "{impersonationLevel=impersonate}!\\" _
    & strComputer & "\root\cimv2")
Set colComputers = objWMIService.ExecQuery _
    ("Select * from Win32_ComputerSystem")
   
For Each objComputer in colComputers
    errReturn = ObjComputer.Rename (reval)
    If reval <> "" Then
                return=MsgBox ("你确定要重起计算机吗?",vbokcancel+vbexclamation,"注意！")
                If return=vbok Then
                        R.run("Shutdown.exe -r -t 0")
                End if
    End If
Next